Sortiranje liste

program SortirajListu;
type pokelement =^element;
    element = record
            podatak :integer;
            sledeci :pokelement;
            end;
            
function dodaj(p :pokelement; n :integer) :pokelement;
var pom :pokelement;
begin
if p = nil then
    begin
    new(p);
    p^.podatak := n;
    p^.sledeci := nil;
    end
else
    begin
    pom := p;
    while pom^.sledeci <> nil do
        pom := pom^.sledeci;
    new(pom^.sledeci);
    pom := pom^.sledeci;
    pom^.podatak := n;
    pom^.sledeci := nil;
    end;
dodaj := p;
end;

procedure stampaj_listu( p:pokelement );
var pom:pokelement;
begin
pom := p;
if p <> NIL then
	begin
	repeat
		write(pom^.podatak,' ');
	    pom:=pom^.sledeci;
	until pom = NIL;
	writeln;
	end
else
	writeln('Lista je prazna.');
writeln;
end;

function sortirajListu(p: pokelement): pokelement;
var sortirano, trenutni, novi: pokelement;
begin
sortirano := NIL;
while p <> NIL do
    begin
    novi := p;
    p := p^.sledeci;
    if (sortirano = NIL) or (novi^.podatak <= sortirano^.podatak) then
        begin
        novi^.sledeci := sortirano;
        sortirano := novi;
        end
    else
        begin
        trenutni := sortirano;
        while (trenutni^.sledeci <> NIL) and (trenutni^.sledeci^.podatak < novi^.podatak) do
            trenutni := trenutni^.sledeci;
        novi^.sledeci := trenutni^.sledeci;
        trenutni^.sledeci := novi;
        end;
    end;
sortirajListu := sortirano;
end;

var x, i, n :integer;
    glava :pokelement;
    
begin
glava := nil;
writeln('Unesi broj elemenata u listi:');
readln(n);
for i:=1 to n do
		begin
		writeln('Unesi ',i,'. element:');
    readln(x);
		glava := dodaj(glava, x);
		end;
writeln('Kreirana lista pre sortiranja je:');
stampaj_listu( glava );
writeln;
glava := sortirajListu(glava);
writeln('Kreirana lista posle sortiranja je:');
stampaj_listu(glava);
end.